Настройка MikroTik пополам как роутер и свич

Приведу пример настройки MikroTik как два разных устройства, коммутатор(свич) и маршрутизатор(роутер).
Порты 1-5 и sfp1 будут работать как свич, в качестве роутера будут порты: LAN 6-9 и wlan1, WAN — 10.

Интернет будет приходить по двум кабелям, первый в свич к sfp1, второй в 10 порт, если кабель интернета только один — подключим его в sfp1 и соединим пачкордом 10 порт роутера с любым портов свича, но лучше обойтись без патчкорда и на «bridge-switch» указать вручную MAC-адрес одного из портов которые в него входят (чтобы не менялся), включить DHCP клиент для «bridge-switch» и в фаерволе настроить маскарадинг на этот бридж.

Сделаем два бриджа:

/interface bridge
add name=bridge-router
add name=bridge-switch

Настроим порты:

/interface ethernet
set [ find default-name=ether2 ] name=ether2-master
set [ find default-name=ether3 ] master-port=ether2-master
set [ find default-name=ether4 ] master-port=ether2-master
set [ find default-name=ether5 ] master-port=ether2-master
set [ find default-name=ether6 ] name=ether6-master
set [ find default-name=ether7 ] master-port=ether6-master
set [ find default-name=ether8 ] master-port=ether6-master
set [ find default-name=ether9 ] master-port=ether6-master
set [ find default-name=ether10 ] name=ether10-Gataway
set [ find default-name=sfp1 ] name=sfp1-toNetwork1
set [ find default-name=ether1 ] master-port=ether2-master

Добавим порты к бриджам:

/interface bridge port
add bridge=bridge-switch interface=ether2-master
add bridge=bridge-switch interface=sfp1-toNetwork1
add bridge=bridge-router interface=wlan1
add bridge=bridge-router interface=ether6-master

Настроим беспроводную сеть:

/interface wireless
set [ find default-name=wlan1 ] band=2ghz-b/g/n channel-width=20/40mhz-Ce disabled=no distance=indoors frequency=auto mode=ap-bridge ssid=WiFi tx-power=30 tx-power-mode=all-rates-fixed wireless-protocol=802.11

Настроим диапазон адресов для DHCP сервера:

/ip pool
add name=dhcp ranges=192.168.0.10-192.168.0.254

Настроим DHCP сервер:

/ip dhcp-server
add address-pool=dhcp disabled=no interface=bridge-router name=dhcp
/ip dhcp-server network
add address=192.168.0.0/24 dns-server=8.8.8.8,8.8.4.4 gateway=192.168.0.1 netmask=24

Пропишем внутренний IP роутеру:

/ip address
add address=192.168.0.1/24 interface=bridge-router network=192.168.0.0

Включим DHCP клиент WAN порту роутера:

/ip dhcp-client
add comment=defconf dhcp-options=hostname,clientid disabled=no interface=ether10-Gataway

Настроим DNS:

/ip dns
set allow-remote-requests=yes
/ip dns static
add address=192.168.0.1 name=router

Включим NAT роутеру:

/ip firewall nat
add action=masquerade chain=srcnat out-interface=ether10-Gataway

Настроим стандартные правила Firewall, разрешим пинг и доступ к web из вне:

/ip firewall filter
add chain=input comment="defconf: accept ICMP" protocol=icmp
add chain=input comment="defconf: accept established,related" connection-state=established,related
add action=drop chain=input comment="defconf: drop all from WAN" in-interface=ether10-Gataway
add action=fasttrack-connection chain=forward comment="defconf: fasttrack" connection-state=established,related
add chain=forward comment="defconf: accept established,related" connection-state=established,related
add action=drop chain=forward comment="defconf: drop invalid" connection-state=invalid
add action=drop chain=forward comment="defconf:  drop all from WAN not DSTNATed" connection-nat-state=!dstnat connection-state=new in-interface=ether10-Gataway
add chain=input dst-port=80 protocol=tcp

Все.

Смотрите также мою статью:
Автоматическое переключение между резервными линиями на MikroTik (RouterOS)

Вливайтесь в общение

1 комментарий

Добавить комментарий

  1. День добрый!
    Спасибо за статью — во многом помогла разобраться, но вопросы остались ;)

    Хочу настроить похожую конфигурацию, но с некоторыми отличиями
    Провайдер один, дает четыре IP по медному кабелю.
    Подключаем его в свитч (1-5 порты) в 1-й порт
    К портам 2-3 подключаем другое оборудование c остальными IP от провайдера.
    Роутер (6-10 порты) — выход во внутреннюю сеть.
    Хотелось бы так-же избавиться от линка между свичем и 10 портом.

    Не подскажете, что изменить в Вашей конфигурации?

Больше на IT Blog

Оформите подписку, чтобы продолжить чтение и получить доступ к полному архиву.

Continue reading