Настройка DDNS клиента NO-IP в Mikrotik RouterOS

После регистрации на сайте www.noip.com, необходимо приступить к настройке маршрутизатора.

Создаем новый скрипт, например с именем «no-ip_ddns_update» и правами read, test, write. Через графический интерфейс меню находится в System -> Scripts.

В первых четверых строках необходимо указать имя зарегистрированного пользователя, его пароль, имя домена, если доменов несколько, то можно писать через запятую, имя сетевого интерфейса который смотрит в интернет, если используется PPOE, то необходимо указать его.

Текст скрипта:

:local noipuser "NOIP_USER"
:local noippass "NOIP_PASSWORD"
:local noiphost "NOIP_HOST"
:local inetinterface "WAN_INTERFACE"

:global previousIP

:if ([/interface get $inetinterface value-name=running]) do={
# Get the current IP on the interface
   :local currentIP [/ip address get [find interface="$inetinterface" disabled=no] address]

# Strip the net mask off the IP address
   :for i from=( [:len $currentIP] - 1) to=0 do={
       :if ( [:pick $currentIP $i] = "/") do={ 
           :set currentIP [:pick $currentIP 0 $i]
       } 
   }

   :if ($currentIP != $previousIP) do={
       :log info "No-IP: Current IP $currentIP is not equal to previous IP, update needed"
       :set previousIP $currentIP

# The update URL. Note the "\3F" is hex for question mark (?). Required since ? is a special character in commands.
       :local url "http://dynupdate.no-ip.com/nic/update\3Fmyip=$currentIP"
       :local noiphostarray
       :set noiphostarray [:toarray $noiphost]
       :foreach host in=$noiphostarray do={
           :log info "No-IP: Sending update for $host"
           /tool fetch url=($url . "&hostname=$host") user=$noipuser password=$noippass mode=http dst-path=("no-ip_ddns_update-" . $host . ".txt")
           :log info "No-IP: Host $host updated on No-IP with IP $currentIP"
       }
   }  else={
       :log info "No-IP: Previous IP $previousIP is equal to current IP, no update needed"
   }
} else={
   :log info "No-IP: $inetinterface is not currently running, so therefore will not update."
}

Далее добавляем в планировщик задание которое будет обновлять информацию NO-IP DDNS. Через графический интерфейс меню находится в System — Sheduler.
Через консоль команда выглядит следующим образом:

system scheduler add comment="Update No-IP DDNS" disabled=no interval=5m name=no-ip_ddns_update on-event=no-ip_ddns_update policy=read,write,test

Альтернативный скрип, написан по информации на http://www.noip.com/integrate/request и http://wiki.mikrotik.com/wiki/Manual:Scripting-examples

##############Script Settings##################
:local NOIPUser "no-ip.com ЛОГИН"
:local NOIPPass "no-ip.com ПАРОЛЬ"
:local WANInter "ИМЯ_WAN_ИНТЕРФЕЙСА"
###############################################

:local NOIPDomain "$NOIPUser.no-ip.org"
:local IpCurrent [/ip address get [find interface=$WANInter] address];
:for i from=( [:len $IpCurrent] - 1) to=0 do={ 
  :if ( [:pick $IpCurrent $i] = "/") do={ 
    :local NewIP [:pick $IpCurrent 0 $i];
    :if ([:resolve $NOIPDomain] != $NewIP) do={
      /tool fetch mode=http user=$NOIPUser password=$NOIPPass url="http://dynupdate.no-ip.com/nic/update\3Fhostname=$NOIPDomain&myip=$NewIP" keep-result=no
      :log info "NO-IP Update: $NOIPDomain - $NewIP"
     }
   } 
}

Настройка DDNS клиента NO-IP в Mikrotik RouterOS: 5 комментариев

  1. К сожалению выхожу в Интернет через NAT, соответвенной мой MikroTik получает на внешнем интерфейсе локальный ip-адрес. Ваш скрипт запрашивает ip-адрес с MikroTik и передает на noip.com, в итоге на noip.com красуется мой локальный ip-адрес.
    Для меня это не вариант! Подскажите, как можно узнать свой внешний ip-адрес по другому, например через сайт 2ip.ru и уже потом передать его на noip.com.

    PS. Сижу через NAT, Интернет получаю от товарища, который пробросил для меня 4 порта.
    Как вариант товарищу, самому настроить noip.com — но не хочу его об этом просить.
    Я просто не совсем знаком с программированием, но думаю для знающего человека не проблема написать скрипт парсинга с 2ip.ru

    Спасибо.

    1. Как вариант можно так получить свой ip за NAT-ом

      # Get current ip and save it to MikroTik
      :local sFileName "dyndns.checkip.html";
      /tool fetch mode=http url="http://checkip.dyndns.org/$sFileName";
      :delay 2;
      :local sIPFile [/file get $sFileName contents];
      /file remove $sFileName;
      # Parse current ip
      :local iIPStart [:find $sIPFile ": " -1];
      :set iIPStart ($iIPStart + 2);
      :local iIPEnd [:find $sIPFile "" -1];
      :local sCurIP [:pick $sIPFile $iIPStart $iIPEnd];
      :log info "---- Current IP: $sCurIP";

  2. Можно и так.
    1. Включить IP->Cloud
    2. В скрипте заменить
    :local currentIP [/ip address get [find interface=»$inetinterface» disabled=no] address]
    на :local currentIP [ /ip cloud get public-address ]
    3. Убрать исключение маски 12-17 строки.

  3. Подскажите, пожалуйста, как мне сделать следующее:
    Провайдер — Ростелеком, сижу за NAT, получаю серый IP (ppoe сессия) вида 100.104.194.15, белый IP — 81.177.127.181 Оба скрипта прекрасно работают, но выдают на no-ip.com белый IP, а мне нужно чтобы записывался «серый». В логах работы скрипта «NO-IP Update: mysite.zapto.org — 100.104.194.15», т.е. так как мне надо, но на сайт no-ip.com пишется именно белый IP.

  4. здравствуйте! У меня такая же проблема только с dyn.com(динднс) нат выключаю инет не работает а с ним на dyn.com(динднс) показывает локальный ip. Напишите плз скрипт очень нужен, заранее спс.

Добавить комментарий